Criando Desconto [RESOLUÇÃO]

Conforme proposto, para descobrir o desconto da venda levando em cosideração sua categoria e sua quantidade, utilizei a fórmula:

=ÍNDICE('Cadastros Auxiliares'!$B$8:$E$13;CORRESP([@Qtd];'Cadastros Auxiliares'!$B$8:$B$13;1);CORRESP(PROCX([@Código];TB_Produtos[[#Tudo];[Código]];TB_Produtos[[#Tudo];[Categoria]]);'Cadastros Auxiliares'!$B$8:$E$8;0))

Abaixo algumas explicações sobre essa fórmula partindo de tudo que foi aprendido:

A fórmula ÍNDICE(matriz;num_linha;[num_coluna]) é utilizada nesse exercício para retornar o valor do desconto cuja orientação para sua localização é a linha e a coluna dentro da matriz formada por valores correspondentes a essas informações. Mas sozinha ela não conseguirá atingir o objetivo, pois haverá uma necessidade de alimentar esses dois parametros (linha e coluna), e para tal, utilizaremos a CORRESP(valor_procurado;matriz_procurada;[tipo de correspondência]).

Nisto, a explicação da fórmula usada no desavio fica, por partes e respeitando a expressão ÍNDICE() e CORRESP():

=ÍNDICE(

MATRIZ = as informações contidas na tabela localizada na aba "CADASTROS AUXILIARES" que compreende entre as células B8 até ( : ) E13. Na fórmula corresponde a essa parte: 'Cadastros Auxiliares'!$B$8:$E$13

NUM_LINHA = na matriz que foi utilizada em CADASTROS AUXILIARES, as linhas correspondem as quantidades vendidas, e assim, para que seja detectado a quantidade vendida naquele lançamento da aba VENDAS utilizamos uma CORRESP() aplicada para localizar em qual posição pertence essa quantidade . Então, a fómula ficou assim, substituindo a parte NUM_LINHA:

=CORRESP(valor_procurado;matriz_procurada;[tipo de correspondência])
=CORRESP([@Qtd];'Cadastros Auxiliares'!$B$8:$B$13;1

Onde:

• valor_procurado = [@Qtd]: coluna E da planilha da aba VENDAS;

• matriz_procurada = Cadastros Auxiliares'!$B$8:$B$13: seleção de B8 até ( : ) B13 que é aonde está localizada as linhas que contém as quantidades;

• [tipo de correspondência] = 1: o numero 1 utilizado no final da fórmula simboliza que não queremos um numero exato, pois na planilha existem numeros que não aparecem, mas que precisam ser considerados na fórmula se a quantidade vendida for um deles;

[NUM_COLUNA] - para essa parte da fórmula, a localização vai ser pela categoria do produto vendido, que está compreendida também na matriz que estamos usando. Na aba VENDAS não temos por escrito quais são as categorias, mas temos os códigos que ajudam a identificar através da fórmula PROCX, ou seja, ao invés de selecionar uma célula em que essa informação já existe, vamos pedir para que fórmula procure aonde essa informação está.

=CORRESP(valor_procurado;matriz_procurada;[tipo de correspondência])
=CORRESP(PROCX([@Código];TB_Produtos[[#Tudo];[Código]];TB_Produtos[[#Tudo];[Categoria]]);'Cadastros Auxiliares'!$B$8:$E$8;0))

Onde:

• valor_procurado = PROCX([@Código];TB_Produtos[[#Tudo];[Código]];TB_Produtos[[#Tudo];[Categoria]]):

  • [@Código]: informação da coluna D da matriz na aba VENDAS, que é aonde é informado o COD do Produto;
  • TB_Produtos[[#Tudo];[Código]]: seleção da coluna que corresponde ao código do item mas na aba PRODUTOS que vamos procurar;
  • TB_Produtos[[#Tudo];[Categoria]]): seleção da coluna que corresponde à categoria mas na aba PRODUTOS que precisa retornar;

• matriz_procurada = Cadastros Auxiliares'!$B$8:$B$13: seleção de B8 até ( : ) E8 que é aonde está localizada colunas linhas que contém as informações de categoria;

• [tipo de correspondência] = 0 : pois queremos a informação exata de acessório, pois ele não corre o risco de ter acessórios além do que já tabelado.

)

E por fim, ficou assim: