[Dúvida] Erro no projeto

Oi, Bruno! Tudo bem?

Desculpe pela demora em te responder.

Esse erro está acontecendo devido ao conteúdo presente nos parâmetros Query. Na suas primeira aparição, o código correto é este:

Query = [
    page = Number.ToText(numeroPagina)
]

Na segunda ocorrência de Query, precisamos escrever o seguinte trecho:

Query = [
    page = "1"
]

Observe que, em seu código, essa ordem foi trocada!

Além disso, durante a criação de #Tabela, lembre-se de deixar o nome das colunas com inicial em maiúsculo, dessa forma:

#"Tabela" = 
    Table.ExpandRecordColumn(
        Table.ExpandListColumn(
            #table(
                type table
                [ Pagina=text, Dados=list],
                #"Lista Dados"
            ), 
            "Dados"
        ),
        "Dados", 
        {"id", "nome", "email", "crm", "especialidade"},
        {"Id", "Nome", "Email", "CRM", "Especialidade"}
    )

Após alterar esses detalhes, a execução dos comandos acontecerá sem erros! Caso queira obter o código por completo, aqui está:

let
    #"Requisição" =
            (numeroPagina) =>
        Json.Document(
            Web.Contents("http://localhost:8080",
            [
                RelativePath = "/medicos",
                Query = [
                    page = Number.ToText(numeroPagina)
                ]
            ])
    ) [content],

    #"Total Paginas" =
    Json.Document(
        Web.Contents("http://localhost:8080",
        [
            RelativePath = "/medicos",
            Query = [
                page = "1"
            ]
        ])
    ) [totalPages],

    #"Lista Paginas" = {0 .. #"Total Paginas"-1},

    #"Lista Dados" = List.Transform(
            #"Lista Paginas",
            each {_, #"Requisição"(_)}
            ),
                            
    #"Tabela" = 
        Table.ExpandRecordColumn(
            Table.ExpandListColumn(
                #table(
                    type table
                    [ Pagina=text, Dados=list],
                    #"Lista Dados"
                ), 
                "Dados"
            ),
            "Dados", 
            {"id", "nome", "email", "crm", "especialidade"},
            {"Id", "Nome", "Email", "CRM", "Especialidade"}
        )
in
    #"Tabela"

Espero ter ajudado, Bruno! Fico à disposição em caso de dúvidas.

Abraços.